pkgname=jruby
pkgver=1.6.5.1
pkgrel=1
pkgdesc="JRuby is 100% pure-Java implementation of the Ruby programming language."
arch=(any)
url="http://www.jruby.org"
license=(CPL GPL2 LGPL2.1 custom)
depends=(java-runtime)
options=(!strip)
source=("http://$pkgname.org.s3.amazonaws.com/downloads/$pkgver/$pkgname-bin-$pkgver.tar.gz")
md5sums=('246a7aa2b7d7e6e9e8a0c2e282cbcfd0')

if false; then
makedepends=(java-environment apache-ant)
build() {
  cd "$srcdir/jruby"
  ant dist-bin
  tar -C .. -xf dist/$pkgname-bin-$pkgver.tar.gz
}
fi

package() {
  cd "$pkgdir"

  mkdir -p "$pkgdir/opt/jruby"

  # copy everything except the bin directory
  for f in docs lib samples share tool COPYING LICENSE.RUBY README; do
    cp -r "$srcdir/jruby-$pkgver/$f" opt/jruby
  done

  mkdir -p "$pkgdir/opt/jruby/bin"

  # copy j* executables
  for f in jgem jirb jruby jrubyc; do
    cp "$srcdir/jruby-$pkgver/bin/$f" opt/jruby/bin
  done
  # copy other executables and rename them to j*
  for f in ast rake rdoc ri testrb; do
    cp "$srcdir/jruby-$pkgver/bin/$f" "opt/jruby/bin/j$f"
  done

  # create symlinks tu /usr/bin
  mkdir -p "$pkgdir/usr/bin"
  cd "$pkgdir/usr/bin"
  for f in "$pkgdir"/opt/jruby/bin/*; do
    ln -s ../../opt/jruby/bin/$(basename $f) .
  done

  mkdir -p "$pkgdir/usr/share/licenses/$pkgname"
  cd "$pkgdir/usr/share/licenses/$pkgname"
  ln -s ../../../../opt/jruby/COPYING .
}